jadiema

After several years of launching micro-rockets, I developed a data-logger based on Arduino platform that measures some flight parameters, such as maximum flight altitude, pressure, temperature...

The micro-rocket, the smallest of the family powered by solid propellant rocket motors, is extremely easy to do! The micro-rocket allows to learn safe flight conditions of a launcher. Using a cardboard tube, balsa and plastic plates, you can perform a micro-rocket rising more than 100 meters high!
It is then necessary to provide a parachute for reducing the lowering speed of the microrocket.

CNES and Planète Sciences regularly organize events to guide you in building and launching your microrockets: http://www.cnes-jeunes.fr/web/CNES-Jeunes-fr/8159-construire-et-lancer-une-microfusee.php

Micro-rocket characteristics:

Ogive + Electronics ~ 60grs

Micro rocket body + ailerons ~60grs

Total weight: ~120grs

Example of launch data:

Solid Propellant (D9-3 type) :

Some videos as example:

From inboard camera (first try):

From smartphone:

From inboard camera (second try):

1 - Altitude: near 300m in 5s, average speed ~220km/h !!!!

2 - Pressure:

Solid Propellant (C6-3 type) :

Micro-rocket launch video:

1 - Altitude: near 150m in 2.5s, average speed ~220km/h !!!!

(Rq: plotted as relative altitude / sea)

2 - Pressure:

Some nice shots from sunday 29/01/2017

Materials needed:
In board camera:
- Mini DVR 808 16 Car Key Chain Camera HD: http://www.ebay.com/itm/Mini-DVR-808-16-V3-Lens-D-Car-Key-Chain-Micro-Camera-HD-720P-Pocket-Camcorder-/180937263580?pt=US_Surveillance_Digital_Video_Recorders_Cards&hash=item2a20b389dc

For the micro-rocket:

- CNES tube (1.8cm internal diameter)

- Aluminum paper

- 18mm solid propellant (C6-3 type) : http://www.miniplanes.fr/motorisation-fusees/moteur-propulseur-c6-3-x6-p-68125.html
or
- 18mm solid propellant (D9-3 type) : http://www.miniplanes.fr/motorisation-fusees/moteur-propulseur-d9-3-x6-p-68132.html

- Parts made with my 3D printer:

o Aileron: http://www.thingiverse.com/thing:448665/#files

o Rocket head containing electronics: http://www.thingiverse.com/thing:448665/#files

For electronics:

- 1 Arduino Nano: http://arduino.cc/en/Main/arduinoBoardNano

- 1 Shield micro SD (catalex.taobao.com): - http://item.taobao.com/item.htm?spm=a1z10.1.w4004-8438023200.10.jnqqG5&id=19306030373gold or http://www.aliexpress.com/store/product/1Pcs-Micro-SD-Storage-Expansion-Board-Mciro-SD-TF-Card-Memory-Shield-Module-SPI-For-Arduino/1199788_1773979975.html

- 1 micro SD card

- 1 Pressure sensor BMP085: https://www.sparkfun.com/products/retired/11282

o https://www.sparkfun.com/tutorials/253

- 1 Turnigy Li-Po battery 300mA.h 1S 3.7V 35C: http://www.hobbyking.com/hobbyking/store/__17808__turnigy_nano_tech_300mah_1s_35c_lipo_pack_suits_fbl100_and_blade_mcpx_.html

NEW VERSION with Arduino Pro Mini:

Same as above except :
- 1 Pressure sensor BMP180: https://www.sparkfun.com/products/11824

- 1 Arduino Pro Mini: http://arduino.cc/en/Main/ArduinoBoardProMini

---------------------------------------------------------------------------------------------------------------

The wiring is quite straightforward:

SD Shield attached to SPI bus as follows:
** MOSI - pin 11
** MISO - pin 12
** CLK - pin 13
** CS - pin 10

BMP180 or BMP085 wiring
** SDA - A4
** SCL - A5
** VCC - 5V
** GND - GND

Li-Po battery (3.7V) directly plugged into the 5V pin.

---------------------------------------------------------------------------------------------------------------
ARDUINO CODE:

/* BMP085 Extended Example Code
by: Jim Lindblom
SparkFun Electronics
date: 1/18/11
updated: 2/26/13
license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/

Get pressure and temperature from the BMP085 and calculate
altitude. Serial.print it out at 9600 baud to serial monitor.

Update (7/19/11): I've heard folks may be encountering issues
with this code, who're running an Arduino at 8MHz. If you're
using an Arduino Pro 3.3V/8MHz, or the like, you may need to
increase some of the delays in the bmp085ReadUP and
bmp085ReadUT functions.

Update J. Grisolia (2014)
BMP180

SD card datalogger
This example shows how to log data from three analog sensors
to an SD card using the SD library.
The circuit:
* analog sensors on analog ins 0, 1, and 2
* SD card attached to SPI bus as follows:
** MOSI - pin 11
** MISO - pin 12
** CLK - pin 13
** CS - pin 10

Pins SDA & SCL
BMP085 wiring
** SDA - A4
** SCL - A5
** VCC - 5V
** GND - GND

*/

#include <Wire.h>
#include <SD.h>

#define DEBUG
//#define DEBUG_BMP085
int tempomesure = 25; //temporisation de la boucle
unsigned long t0=0;
unsigned long prevMillis=0;
//BMP085
#define BMP085_ADDRESS 0x77 // I2C address of BMP085, idem BMP1080
const unsigned char OSS = 0; // Oversampling Setting
// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;

// Use these for altitude conversions
const float p0 = 101325;     // Pressure at sea level (Pa)
float altitude;

//SD CARD
const int chipSelect = 10;

long fileNum = 0; // maximum 99999
String fileName;
char name[13];
File dataFile;

void incFileNum() { // generate next file name:
String s = "dat" + String(++fileNum) + ".txt";
s.toCharArray(name,13);
}

void save(String s) {
dataFile = SD.open(name, FILE_WRITE);
if (dataFile) {
    dataFile.println(s);
    dataFile.close();
    Serial.println(s);
}
else Serial.println("error opening " + String(name));
}

void setup()
{
pinMode(chipSelect, OUTPUT);

// Open serial communications and wait for port to open:
#if defined(DEBUG) || defined(DEBUG_BMP085)
Serial.begin(115200);
while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
}
Serial.print("Initializing SD card...");
// make sure that the default chip select pin is set to
// output, even if you don't use it:
// see if the card is present and can be initialized:
if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
}
Serial.println("card initialized.");
#endif
//Efface le fichier initial
// SD.remove("DATA.txt");

//GESTION DES NOMS DES FICHIERS
//--------------------------------------------------
incFileNum(); // set it to datxxxx.txt
while (SD.exists(name)) incFileNum();

#ifdef DEBUG
Serial.println("new file name: " + String(name));
#endif
//--------------------------------------------------
save("DATA MICRO FUSEES");
save("t(ms)|Altitude(m)*100|Pression(Pa)|Temperature(C)*0.1");

//CAPTEUR bmp085
Wire.begin();
bmp085Calibration();
//initialisation du temps:
unsigned long prevMillis = millis();
}

void loop()
{
if ((millis() - prevMillis) > tempomesure) {
///////////////////////////////////////////////////////////////
// Capteur pression et temperature
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));

#ifdef DEBUG_BMP085
Serial.print("Temperature: ");
Serial.print(temperature, DEC);
Serial.println(" *0.1 deg C");
Serial.print("Pressure: ");
Serial.print(pressure, DEC);
Serial.println(" Pa");
Serial.print("Altitude: ");
Serial.print(altitude, 2);
Serial.println(" m");
Serial.println();
#endif
//delay(tempomesure);
///////////////////////////////////////////////////////////////
// make a string for assembling the data to log:

String dataString = "";
//OLD
//t0 = t0 + (millis() - prevMillis);
//NEW
t0 = millis();
/*
#ifdef DEBUG
Serial.print("millis():");
Serial.print(millis());
Serial.print(",");
Serial.print("t0:");
Serial.print(t0);
Serial.print(",");
#endif
*/
unsigned int alti = altitude*100;
unsigned long pressu = pressure;
unsigned int tempe = temperature;
dataString = String(t0) + "," + String(alti) + "," + String(pressu) + "," + String(tempe);
// open the file. note that only one file can be open at a time,
// so you have to close this one before opening another.

//File dataFile = SD.open("DATA.txt", FILE_WRITE);
File dataFile = SD.open(name, FILE_WRITE);

// if the file is available, write to it:
if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    #ifdef DEBUG
        // print to the serial port too:
      Serial.println(dataString);
    #endif
}
// if the file isn't open, pop up an error:
else {
    Serial.println("error opening datalog.txt");
}//fin du if dataFile
prevMillis = millis();
}

}// fin de loop

//---------------------------------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------------------

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;

x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;

return ((b5 + 8)>>4);
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;

b6 = b5 - 4000;
// Calculate B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

// Calculate B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
    p = (b7<<1)/b4;
else
    p = (b7/b4)<<1;

x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;

return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
unsigned char data;

Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();

Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available())
    ;

return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;

Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();

Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2)
    ;
msb = Wire.read();
lsb = Wire.read();

return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
unsigned int ut;

// Write 0x2E into Register 0xF4
// This requests a temperature reading
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x2E);
Wire.endTransmission();

// Wait at least 4.5ms
delay(5);

// Read two bytes from registers 0xF6 and 0xF7
ut = bmp085ReadInt(0xF6);
return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;

// Write 0x34+(OSS<<6) into register 0xF4
// Request a pressure reading w/ oversampling setting
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x34 + (OSS<<6));
Wire.endTransmission();

// Wait for conversion, delay time dependent on OSS
delay(2 + (3<<OSS));

// Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);

// Wait for data to become available
while(Wire.available() < 3)
    ;
msb = Wire.read();
lsb = Wire.read();
xlsb = Wire.read();

up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

return up;
}

Eiji Hayashi has recently completed a wonderful game based on the use of LEDs as light sensors and not just as a light emitter. This gives the LASER COMMAND game: http://www.cs.cmu.edu/~ehayashi/projects/lasercommand/

I had a lot of fun doing my version which I added:

1- EEPROM management in order to save High Score. The HIGH SCORE appears just before the start of the game countdown (3/2/1-GO).

2 - A PCB made with ExpressPCB, free software for PCB design.

Here’s the PCB made with Express PCB (http://www.expresspcb.com/)

The equipment needed to perform this LASER COMMAND is the following:

- An Arduino Mini http://arduino.cc/en/Main/ArduinoBoardMini

https://www.sparkfun.com/products/11303

A Matrix 8 * 8: http://www.ebay.fr/itm/2x-2-3-Dispaly-8-8-Dot-Matrix-LED-Segment-Black-Surface-White-Glue-CA-/180884686398?pt=LH_DefaultDomain_0&hash=item2a1d91463e

(be careful to choose the right model (CA or CC) corresponding on the PCB that I made)

- Batteries, I use Li-Ion: http://www.miniinthebox.com/fr/1020mah-piles-de-rechange-de-telephone-portable-nokia-bl-5c-pour-nokia-1100-1108-1110-1111-1112-1116-1200-1208-1209-1255-1280-1315-et-plus_p183508.html?pos=ultimately_buy_3

- Piezo buzzer or better a phone speaker

- Header ...

- Switch

- Some plastic to form the box

- A Laser to play at the game. I use a green laser like this: http://www.miniinthebox.com/fr/laser-pointeur-vert-5mw-2xaaa-_p79213.html. But a blue laser like this will do the job as well, if not better: http://www.miniinthebox.com/fr/stylo-laser-pointeur-bleu-2-piles-aaa-inclues-_p206604.html

The code and the PCB design file are available at:

http://code.google.com/p/my-arduino-projects/downloads/detail?name=LASER_COMMAND_Plus.rar&can=2&q=#makechanges

Be careful, the code was compiled using Arduino 022 IDE.

Do not hesitate to contact me for enhancements/fixes ...

Eiji Hayashi a réalisé récemment un magnifique jeu basé sur l’utilisation de LED comme capteurs de lumière et non pas uniquement comme un émetteur de lumière. Cela donne le jeu LASER COMMAND : http://www.cs.cmu.edu/~ehayashi/projects/lasercommand/

J’ai pris beaucoup de plaisir à réaliser ma version à laquelle j’ai ajoutée :

1 - une gestion de l’EEPROM afin de pouvoir enregistrer des High Score.

Le HIGH SCORE score s’affiche juste avant le décompte de lancement du jeu (3/2/1—GO).

2 - un PCB réalisé avec ExpressPCB, un logiciel libre de conception de circuit imprimé.

Le PCB réalisé avec Express PCB (http://www.expresspcb.com/)

Le matériel nécessaire pour réaliser ce laser command est le suivant

- Un Arduino Mini : http://arduino.cc/en/Main/ArduinoBoardMini

https://www.sparkfun.com/products/11303

- Un Matrix 8*8 :

http://www.ebay.fr/itm/2x-2-3-Dispaly-8-8-Dot-Matrix-LED-Segment-Black-Surface-White-Glue-CA-/180884686398?pt=LH_DefaultDomain_0&hash=item2a1d91463e

(attention à choisir le bon modèle CA ou CC en fonction du PCB que j’ai fait)

- Batteries, j’utilise des Li-Ion : http://www.miniinthebox.com/fr/1020mah-piles-de-rechange-de-telephone-portable-nokia-bl-5c-pour-nokia-1100-1108-1110-1111-1112-1116-1200-1208-1209-1255-1280-1315-et-plus_p183508.html?pos=ultimately_buy_3